99 REM BASIC FILE: HTMTXT.BAS
100 COLOR 0,15:CLS:T$="HTML to PLAIN TEXT CONVERTER     by captainrat":PRINT T$;"~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~"
105 T2$="AN IBM GWBASIC FREEWARE PROGRAM...EMAIL: captainrat23@yahoo.com":PRINT T2$
110 GOSUB 480:PRINT "PRESS F-5 TO STOP;  PRESS F-9 TO EXIT"
120 SHELL "DIR C:\/AD/W"
125 ON ERROR GOTO 350
130 IF D$<>"" THEN LOCATE 20,2:PRINT "current directory: ";D$:CHDIR D$
140 LOCATE 22,2:PRINT "WHICH DIRECTORY? (press ENTER for no change)";:INPUT "\";D$:IF D$="!" THEN 420
145 IF D$="" THEN 170
150 IF MID$(D$,1,1)<>"\" AND MID$(D$,3,1)<>"\" THEN DC$="\"+D$:D$=DC$
160 CHDIR D$
170 CLS:FILES "*.htm"
175 PRINT "press ENTER to return to directory list"
180 PRINT T$:INPUT "NAME OF HTM FILE";H$:IF H$="" THEN 120
185 IF H$="!" THEN 420
190 Y=LEN(H$):FOR X=1 TO Y:HC$=MID$(H$,X,1):IF HC$="." THEN X=Y:GOTO 210
200 G$=G$+HC$
210 NEXT X:P$=G$+".txt":PRINT "output file: ";P$;" o.k.? (y/n)"
220 GOSUB 450:IF R$="N" THEN INPUT "output file name: ";P$
230 PRINT "INPUT: ";H$:PRINT "OUTPUT: ";P$
240 OPEN H$ FOR INPUT AS #1:OPEN P$ FOR OUTPUT AS #2
250 M$="~~~captainrat is a genius!  it worked!~~~~~~~~~"
260 IF EOF(1) THEN E=1:GOTO 350
270 ON ERROR GOTO 350
280 LINE INPUT #1,I$:LI=LEN(I$):FOR X=1 TO LI:C$=MID$(I$,X,1):IF C$="<" THEN OFLAG=1
290 IF C$=">" THEN OFLAG=0:GOTO 330
300 IF OFLAG THEN 330
310 NU$=NU$+C$
320 N=N+1
330 NEXT X:PRINT#2,NU$:NU$="":PRINT ".";
340 GOTO 280
350 BEEP:E=ERR:IF E=62 THEN RESUME 370
355 IF E=53 THEN RESUME 510
360 IF E<>62 THEN PRINT E;" ERROR IN ";ERL:STOP
370 CLOSE:S$="type "+P$:SHELL S$
380 REM one could shell to a file viewer or editor here
390 LOCATE 21,2:PRINT M$,"new file: ";P$
400 LOCATE 22,20:PRINT "DELETE ";H$;"? (y/n)":GOSUB 450
410 IF R$="Y" THEN KILL H$
420 PRINT "R=RUN AGAIN  Q=QUIT":GOSUB 450
430 IF R$="Q" THEN PRINT T$:PRINT T2$:PRINT "PRESS F-9 TO RETURN TO O.S.":END
440 G$="":GOTO 100
450 R$=INKEY$:IF R$="" THEN 450
460 RX=ASC(R$):IF RX>90 THEN RX=RX-32:R$=CHR$(RX)
465 IF R$="!" THEN 420
470 RETURN
480 KEY 9,"SYSTEM"+CHR$(13):KEY 10,"?TIME$"+CHR$(13):KEY 6,"?DATE$"+CHR$(13):KEY 5,"!"+CHR$(13)
490 KEY ON
500 RETURN
510 PRINT "no .htm files listed...":S$="DIR /OE/P":SHELL S$:GOTO 175